You DO NOT need to put the files into a USB stick.
What happens is that the person who wrote the "jp.bat" script, he committed various syntax errors in the script (by including the double quotes of the special arguments, instead of expanding their values), so it will only work as expected when dropping the files from a directory path without blank spaces in its name (ej. the root drive letter of a USB stick).
To fix this issue and let you drop the files from any directory, just replace the "jp.bat" file content with this other:
jp_fixed.bat
Code:
@echo off
cls
jpatch.exe "%~f1" "%~dp0%~nx1_eng.patch" "%~f1.patched"
move "%~f1" "%~f1.bak"
move "%~f1.patched" "%~f1"
pause
---------------------------------------------------------------------------------------
Or else you can use this verbose modification I did:
jp_fixed_verbose.bat
Code:
@ECHO OFF
ECHO:Applying patch...
ECHO:Source file: "%~f1"
ECHO:Patch file: "%~dp0%~nx1_eng.patch"
ECHO:Output file: "%~f1.patched"
ECHO+
("%~dp0jpatch.exe" "%~f1" "%~dp0%~nx1_eng.patch" "%~f1.patched") && (
ECHO:Patch applied.
) || (
ECHO+
ECHO:Error occurred. This program will close now...
PAUSE
EXIT /B 1
)
ECHO+
ECHO:Replacing source file extension to .bak...
(MOVE "%~f1" "%~f1.bak")1>NUL
ECHO+
ECHO:Renaming patched file to source file name...
(MOVE "%~f1.patched" "%~f1")1>NUL
ECHO+
ECHO:Patcher work completed.
PAUSE
EXIT /B 0
That's all. Enjoy.
The forum has a restriction that does not let me edit my own posts after 20 minutes (even when they are still not approved to be published), so I'll share here a newer (better) modification of the verbose script that I shared in my previous post:
jp_fixed_verbose.bat
Code:
@ECHO OFF & Title Star Ocean - Integrity and Faithlessness Patcher
If "%~f1" EQU "" (
ECHO:To use this patcher, you must drop the next
ECHO:files individually to this script file.
ECHO:
ECHO: - FAI_main_ps3_LgJPN.cpk
ECHO: - FAI_main_ps3_VoJPN.cpk
CALL :PrintErrorMessageAndExit ""
)
ECHO:Applying patch...
ECHO:Source file: "%~f1"
ECHO:Patch file: "%~dp0%~nx1_eng.patch"
ECHO:Output file: "%~f1.patched"
ECHO+
("%~dp0jpatch.exe" "%~f1" "%~dp0%~nx1_eng.patch" "%~f1.patched") && (
ECHO:Patch applied.
) || (
CALL :PrintErrorMessageAndExit "Error occurred trying to apply the patch."
)
ECHO+
ECHO:Replacing source file extension to .bak...
(MOVE "%~f1" "%~f1.bak")1>NUL || (
CALL :PrintErrorMessageAndExit "Error occurred trying to rename source file."
)
ECHO+
ECHO:Renaming output file to source full path...
(MOVE "%~f1.patched" "%~f1")1>NUL || (
CALL :PrintErrorMessageAndExit "Error occurred trying to rename output file."
)
ECHO+
ECHO:Patcher work completed. This program will close now...
ECHO+
PAUSE
EXIT /B 0
:PrintErrorMessageAndExit
ECHO+
If "%~nx1" NEQ "" (ECHO:%~nx1)
ECHO:This program will close now...
ECHO+
PAUSE
EXIT 1
---------------------------------------------------------------------------
In addition, I am going to take the opportunity to present the following script with which to use the "PS3 Disc Dumper" program FROM AN ADMINISTRATOR ACCOUNT, for those who need to decrypt the original Japanese Star Ocean disc and want to use that "PS3 Disc Dumper" program without absurd UAC restrictions.
Here it is (I'm the author):
https:// github .com/ElektroStudios/ps3-disc-dumper-UAC-bypass
( I don't have enough privileges to post urls, so join the blank spaces yourself. )
